=SI(test_logique;valeur_si_vrai;valeur_si_faux) Dans ce guide, vous apprenez à écrire une formule SI Excel simple, puis avec plusieurs conditions (ET, OU, SI imbriqué, SI.CONDITIONS, SI.MULTIPLE). Vous l’appliquerez ensuite à du texte, à des dates et à la couleur des cellules. Chaque notion est illustrée par un tableau, une formule et le résultat attendu.
Fonction SI Excel : définition et syntaxe
La fonction SI (IF dans Excel en anglais) pose une question à Excel : le test logique. Si la réponse est VRAI, Excel renvoie le deuxième argument. Si elle est FAUX, il renvoie le troisième.
Les arguments sont séparés par des points-virgules dans Excel en français. Le texte renvoyé s’écrit entre guillemets droits ("). Les nombres s’écrivent sans guillemets ni symbole €.
Sur Google Sheets, la fonction SI s’écrit de la même façon : voir notre guide de la fonction SI sur Google Sheets.
| Argument | Rôle | Exemple |
|---|---|---|
test_logique | La condition à vérifier, construite avec un opérateur de comparaison | B2>=10 |
valeur_si_vrai | Ce qu’Excel affiche ou calcule si la condition est vraie | "Admis" |
valeur_si_faux | Ce qu’Excel affiche ou calcule si la condition est fausse. Facultatif, mais à toujours renseigner : sinon Excel affiche FAUX | "Refusé" |
Pour saisir une fonction SI dans Excel sans erreur de syntaxe, utilisez l’assistant : onglet Formules > Logique > SI. Excel ouvre une fenêtre avec une zone par argument et affiche le résultat avant validation.

Les opérateurs de comparaison de la fonction SI
Le test d’une fonction SI repose sur l’un des six opérateurs ci-dessous. Il n’existe pas d’opérateur « compris entre » : on combine alors deux tests avec ET (voir plus bas). Le détail figure dans notre guide des signes de comparaison dans Excel.
| Opérateur | Signification | Exemple de formule | Résultat si B2 vaut… |
|---|---|---|---|
= | égal à | =SI(B2="Payé";"OK";"Relancer") | « Payé » → OK |
<> | différent de | =SI(B2<>"";"Rempli";"Vide") | « Dupont » → Rempli |
> | strictement supérieur à | =SI(B2>1000;"Grand compte";"Standard") | 1 000 → Standard |
< | strictement inférieur à | =SI(B2<10;"Stock bas";"Stock OK") | 7 → Stock bas |
>= | supérieur ou égal à | =SI(B2>=18;"Majeur";"Mineur") | 18 → Majeur |
<= | inférieur ou égal à | =SI(B2<=30;"Dans les délais";"Hors délai") | 31 → Hors délai |
Attention à la frontière : avec >, la valeur seuil elle-même renvoie FAUX. Avec >=, elle renvoie VRAI.
3 exemples simples de formule SI pour démarrer
Exemple 1 : afficher un texte (Admis / Refusé)
Imaginons un centre de formation qui affiche « Admis » si la note à l’examen atteint 10 sur 20.
| A | B | C | |
|---|---|---|---|
| 1 | Stagiaire | Note /20 | Résultat |
| 2 | Léa | 14 | Admis |
| 3 | Hugo | 9 | Refusé |
| 4 | Inès | 10 | Admis |
En C2, saisissez puis recopiez vers le bas :
=SI(B2>=10;"Admis";"Refusé") Résultat attendu : Admis, Refusé, Admis. Inès est admise parce que l’opérateur est >=.

Exemple 2 : faire un calcul (remise de 10 %)
Imaginons une boutique qui accorde 10 % de remise sur les commandes de 500 € ou plus. La fonction SI peut renvoyer un calcul plutôt qu’un texte.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Commande | Montant (€) | Remise (€) | Net à payer (€) |
| 2 | CMD-101 | 640 | 64 | 576 |
| 3 | CMD-102 | 320 | 0 | 320 |
| 4 | CMD-103 | 500 | 50 | 450 |
=SI(B2>=500;B2*10%;0) Résultat attendu : 64, 0 et 50. Pour obtenir le net à payer, écrivez en D2 =B2-C2.

Exemple 3 : comparer du texte (tarif VIP)
Imaginons un espace de coworking qui facture la journée 49 € aux membres « VIP » et 69 € aux autres.
| A | B | C | |
|---|---|---|---|
| 1 | Client | Statut | Tarif jour (€) |
| 2 | Agence Lumen | VIP | 49 |
| 3 | M. Roche | Standard | 69 |
| 4 | Studio Kappa | vip | 49 |
=SI(B2="VIP";49;69) Résultat attendu : 49, 69, 49. La comparaison de texte ne tient pas compte des majuscules : « vip » vaut « VIP ». En revanche, une espace en trop (« VIP␣ ») fait échouer le test.

Formule Excel SI avec plusieurs conditions : SI + ET, SI + OU
Pour écrire une fonction SI avec plusieurs conditions, placez ET ou OU dans le premier argument. ET renvoie VRAI si toutes les conditions sont remplies. OU renvoie VRAI si au moins une l’est.
SI ET Excel : toutes les conditions doivent être vraies
Imaginons un service comptable qui rembourse automatiquement une note de frais si elle ne dépasse pas 150 € et si le justificatif est fourni.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Salarié | Montant (€) | Justificatif | Décision |
| 2 | Nadia | 120 | Oui | Remboursé |
| 3 | Paul | 180 | Oui | À vérifier |
| 4 | Yanis | 90 | Non | À vérifier |
=SI(ET(B2<=150;C2="Oui");"Remboursé";"À vérifier") Paul dépasse le plafond et Yanis n’a pas de justificatif : une seule condition fausse suffit pour basculer sur « À vérifier ». Plus d’exemples dans notre guide SI ET Excel.
C’est aussi avec ET que l’on teste une valeur « comprise entre » deux bornes, puisque SI n’a pas d’opérateur pour cela. Pour afficher « Rattrapage » quand une note est comprise entre 8 et 12, 12 exclu : =SI(ET(B2>=8;B2<12);"Rattrapage";"Autre cas").

SI OU Excel : une seule condition suffit
Imaginons un service après-vente qui traite en priorité les tickets de type « Panne » ou ceux des clients « Premium ».
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Ticket | Type | Contrat | Traitement |
| 2 | T-501 | Panne | Standard | Prioritaire |
| 3 | T-502 | Question | Premium | Prioritaire |
| 4 | T-503 | Question | Standard | Normal |
=SI(OU(B2="Panne";C2="Premium");"Prioritaire";"Normal") Voir aussi notre guide SI OU Excel.
Fonction SI ET OU Excel : combiner les deux
On peut imbriquer OU dans ET. Ici, la livraison J+1 est proposée si la commande atteint 1 000 € et si la ville est Paris ou Lyon :
=SI(ET(B2>=1000;OU(C2="Paris";C2="Lyon"));"Livraison J+1";"Livraison standard") Résultat : 1 200 € à Lyon → « Livraison J+1 » ; 1 200 € à Nantes → « Livraison standard » ; 800 € à Paris → « Livraison standard ».
SI imbriqué Excel : fonction SI à 2, 3 et 4 conditions
Un SI imbriqué place une fonction SI dans l’argument valeur_si_faux d’une autre. Excel teste les conditions dans l’ordre et s’arrête à la première vraie. Règle d’or : avec >=, partez du seuil le plus haut. Avec <=, partez du plus bas.
Fonction SI imbriquée à 2 conditions (3 résultats)
Imaginons un module validé à partir de 12, rattrapable de 8 à moins de 12, et non validé en dessous de 8.
=SI(B2>=12;"Validé";SI(B2>=8;"Rattrapage";"Non validé")) Résultat : 13 → Validé ; 9 → Rattrapage ; 6 → Non validé.
Fonction SI Excel à 3 conditions : tranches de prime
Imaginons qu’un commercial touche 3 % de son chiffre d’affaires à partir de 100 000 €, 2 % à partir de 50 000 €, 1 % à partir de 20 000 €, et rien en dessous.
| A | B | C | |
|---|---|---|---|
| 1 | Commercial | CA annuel (€) | Prime (€) |
| 2 | Camille | 120 000 | 3 600 |
| 3 | Mehdi | 64 000 | 1 280 |
| 4 | Julie | 25 000 | 250 |
| 5 | Thomas | 15 000 | 0 |
=SI(B2>=100000;B2*3%;SI(B2>=50000;B2*2%;SI(B2>=20000;B2*1%;0)))
SI imbriqué à 4 conditions : les mentions
Barème des mentions sur 20 : Très bien (16 et plus), Bien (14), Assez bien (12), Passable (10), Ajourné en dessous. La note est en colonne A :
=SI(A2>=16;"Très bien";SI(A2>=14;"Bien";SI(A2>=12;"Assez bien";SI(A2>=10;"Passable";"Ajourné")))) Résultat : 17 → Très bien ; 14,5 → Bien ; 12 → Assez bien ; 10 → Passable ; 8 → Ajourné. Comptez quatre « SI( » et quatre parenthèses fermantes à la fin.

Combien de SI peut-on imbriquer ? Excel permet d’imbriquer jusqu’à 64 fonctions SI, mais Microsoft le déconseille. En pratique, au-delà de 3 conditions, passez à SI.CONDITIONS : la formule est plus courte et plus facile à relire.
SI.CONDITIONS : l’alternative moderne au SI imbriqué (Excel 2019 / 365)
SI.CONDITIONS enchaîne des paires « condition ; résultat » sans imbrication. Excel renvoie le résultat de la première condition vraie. On la cherche parfois sous le nom SI.ENS, par analogie avec SOMME.SI.ENS et NB.SI.ENS : ce nom n’existe pas dans Excel. Le barème des mentions devient :
=SI.CONDITIONS(A2>=16;"Très bien";A2>=14;"Bien";A2>=12;"Assez bien";A2>=10;"Passable";VRAI;"Ajourné") La dernière paire VRAI;"Ajourné" joue le rôle du « sinon ». Sans elle, une note de 8 ne remplit aucune condition et Excel renvoie l’erreur #N/A.
Les tranches de prime s’écrivent de la même façon :
=SI.CONDITIONS(B2>=100000;B2*3%;B2>=50000;B2*2%;B2>=20000;B2*1%;VRAI;0) SI.CONDITIONS peut tester jusqu’à 127 conditions. Elle existe dans Excel 2019, 2021, 2024 et Microsoft 365. Dans Excel 2016 et les versions plus anciennes, elle renvoie #NOM? : gardez un SI imbriqué si vos fichiers circulent sur d’anciennes versions.
SI.MULTIPLE : comparer une cellule à une liste de valeurs
Souvent cherchée sous le nom « SI multiple », la fonction SI.MULTIPLE compare une cellule à une liste de valeurs exactes et renvoie le résultat associé à la première qui correspond. Pour traduire un code de service, elle remplace avantageusement trois SI imbriqués :
=SI.MULTIPLE(B2;"A";"Administration";"C";"Commercial";"T";"Technique";"Autre service") Le dernier argument, seul, sert de valeur par défaut ; sans lui, un code inconnu renvoie #N/A. SI.MULTIPLE accepte jusqu’à 126 paires valeur/résultat et existe dans les mêmes versions que SI.CONDITIONS. Elle ne prend pas d’opérateur de comparaison : pour des seuils (>=, <), restez sur SI.CONDITIONS.
Formule SI Excel avec du texte : « égal à » et « contient »
Pour tester un texte exact, comparez avec = et des guillemets :
=SI(A2="Oui";"Inscrit";"Non inscrit") Pour savoir si une cellule contient un mot, SI seul ne suffit pas : =SI(A2="*urgent*";…) ne fonctionne pas, car SI ne gère pas les caractères génériques. Combinez CHERCHE, qui renvoie la position du mot ou une erreur, et ESTNUM, qui transforme cette position en VRAI.
| A | B | |
|---|---|---|
| 1 | Objet du message | Priorité |
| 2 | URGENT – serveur à l’arrêt | À traiter aujourd’hui |
| 3 | Demande de devis | Normal |
| 4 | Facture urgente à valider | À traiter aujourd’hui |
=SI(ESTNUM(CHERCHE("urgent";A2));"À traiter aujourd'hui";"Normal") CHERCHE ignore les majuscules. Elle trouve aussi « urgent » dans « non urgent » : vérifiez vos libellés, ou utilisez TROUVE pour une recherche sensible à la casse. Variante avec NB.SI : =SI(NB.SI(A2;"*urgent*")>0;"À traiter aujourd'hui";"Normal").

Fonction SI avec des dates
Excel stocke les dates sous forme de nombres. Vous pouvez donc les comparer directement à AUJOURDHUI(), qui renvoie la date du jour et se met à jour à chaque ouverture du fichier.
=SI(B2<AUJOURDHUI();"Échéance passée";"À venir") Pour alerter sept jours avant l’échéance, ajoutez un niveau :
=SI(B2<AUJOURDHUI();"En retard";SI(B2-AUJOURDHUI()<=7;"Sous 7 jours";"À venir"))
| Facture | Échéance (B) | Résultat au 26/10/2026 |
|---|---|---|
| F-2041 | 15/10/2026 | En retard |
| F-2042 | 30/10/2026 | Sous 7 jours |
| F-2043 | 20/11/2026 | À venir |

Pour une date fixe, n’écrivez pas « 31/12/2026 » dans la formule : utilisez DATE(2026;12;31). Et protégez les dates vides : une cellule vide vaut 0, donc une date passée, donc « En retard ».
Comment colorer une cellule Excel avec une formule SI (mise en forme conditionnelle)
Une formule SI ne change pas la couleur d’une cellule. C’est la mise en forme conditionnelle qui s’en charge, avec une règle écrite comme le test d’un SI. Exemple : colorer en rouge les factures en retard.
Étape 1. Sélectionnez la plage A2:C20, en commençant par A2.

Étape 2. Cliquez sur Accueil > Mise en forme conditionnelle > Nouvelle règle > Utiliser une formule pour déterminer pour quelles cellules le format sera appliqué. Saisissez :
=$B2<AUJOURDHUI() Pas besoin d’écrire SI : la règle doit simplement renvoyer VRAI ou FAUX. Le $ devant B fige la colonne de l’échéance pour que toute la ligne se colore.

Étape 3. Cliquez sur Format > onglet Remplissage, choisissez une couleur (ici le rouge), puis validez deux fois avec OK.

Lignes vides : une échéance vide vaut 0, donc une date passée. Si la plage sélectionnée contient des lignes vides, comme ici les lignes 5 à 20, elles se colorent aussi. Pour les ignorer, écrivez la règle ainsi : =ET($B2<>"";$B2<AUJOURDHUI()).
Pour colorer selon le résultat d’une colonne calculée par SI, écrivez la règle sur ce résultat, par exemple =$C2="En retard". Plus d’options dans notre guide de la mise en forme conditionnelle.
Combiner SI avec SOMME.SI, NB.SI, SIERREUR et RECHERCHEV
SI + SOMME.SI : comparer un total à un objectif
SOMME.SI additionne les montants qui respectent un critère. Placé dans le test d’un SI, il permet d’afficher un statut sur un total.
=SI(SOMME.SI(B2:B50;"Nord";C2:C50)>=50000;"Objectif Nord atteint";"Objectif Nord non atteint") Voir notre guide SOMME.SI et SOMME.SI.ENS.
SI + NB.SI : repérer les doublons
NB.SI compte les occurrences d’une valeur. Si un numéro de client apparaît plus d’une fois, la formule le signale :
=SI(NB.SI($A$2:$A$500;A2)>1;"Doublon";"") Voir notre guide NB.SI et NB.SI.ENS.
Formule SI erreur : SI + SIERREUR
SI ne gère pas les erreurs : si son test produit #DIV/0! ou #N/A, il renvoie la même erreur. Enveloppez la formule dans SIERREUR :
=SIERREUR(SI(B2/C2>=1;"Objectif atteint";"En dessous");"Objectif manquant") Si C2 (l’objectif) est vide ou nul, la division échoue et la cellule affiche « Objectif manquant ». Voir notre guide SIERREUR.
SI + RECHERCHEV : décider à partir d’une valeur recherchée
RECHERCHEV récupère le prix d’un article dans un onglet Tarifs. SI décide ensuite du circuit de validation. SIERREUR gère les références inconnues :
=SIERREUR(SI(RECHERCHEV(A2;Tarifs!A:B;2;FAUX)>500;"Validation manager";"Validation auto");"Référence inconnue") Voir notre guide RECHERCHEV.
Les 5 erreurs courantes de la fonction SI et leur correction
| Erreur | Formule fautive | Ce qui se passe | Correction |
|---|---|---|---|
| 1. #NOM? : fonction inexistante ou mal écrite | =SI.ENS(A2> | SI.ENS n’existe pas dans Excel : Excel ne reconnaît pas le nom et affiche #NOM? | =SI.CONDITIONS(A2> |
| 2. Guillemets oubliés ou typographiques | =SI(B2> | Excel prend Admis pour un nom inconnu : #NOM?. Même effet avec des guillemets « » ou “ ” copiés depuis Word | =SI(B2> avec des guillemets droits. Pas de guillemets autour des nombres |
| 3. Parenthèses mal fermées | =SI(B2> | Excel refuse la formule ou propose une correction automatique qui peut être fausse | Une parenthèse fermante par « SI( » ouvert : …"Non validé")) |
| 4. Virgule au lieu du point-virgule | =SI(B2> | Syntaxe anglaise copiée d’un site américain : Excel en français la rejette | Remplacer les virgules séparatrices par des points-virgules. La virgule reste le séparateur décimal : B2*0, |
| 5. Cellule vide traitée comme 0 | =SI(B2> avec B2 vide | Un stagiaire sans note s’affiche « Refusé » ; une date vide s’affiche « En retard » | Tester le vide d’abord : =SI(B2=""; |


Aller plus loin : la formation Excel en visio individuelle
Vous savez écrire une fonction SI. L’étape suivante consiste à l’appliquer à vos propres fichiers : reportings, plannings, suivis clients.
Notre formation Excel certifiante fait travailler la fonction SI et les SI imbriqués, RECHERCHEV, la mise en forme conditionnelle et les tableaux croisés dynamiques. La formule Accompagnée associe la plateforme en ligne à des séances de visio individuelle avec un formateur.
- Passage de la certification ENI ou ICDL inclus
- Un an d’accès à la plateforme et aux supports
- Organisme certifié Qualiopi
Comparer les formules de formation Excel · Tester mon niveau gratuitement · Former une équipe





